Bu yazıda Mikrotik RouterOS ile fiber internet bağlantısı sağlayacağız. Bu işlemi yapabilmek için PPPoE erişim bilgilerine sahip olmamız gerekiyor. Servis sağlayıcımızın verdiği cihaz yerine neden kendi cihazımızı kullandığımızı merak ediyorsanız, serinin bir önceki yazısı “Neden?“i okuyabilirsiniz.

Yapılan işlemin RouterOS üzerinde daha önceden tanımlamış olduğunuz kurallardan etkilenmemesi için yedek almanızı ve cihazı sıfırlamanızı tavsiye ederim. Aşağıdaki talimatlar Mikrotik terminaline gireceğiniz komutlardan oluşuyor, ancak komutları okuyarak aynı yapılandırmayı WinBox/WebFig arayüzleri üzerinden uygulamak da mümkün.

Kablosuz erişim için arayüzleri yapılandırarak başlayalım. Örnek olması açısından bir tane 2.4 GHz, bir tane 5 GHz arayüz tanımlamasını aşağıda görebilirsiniz. (Ağ ismi, parola ve kablosuz arayüzünü kendi ortamınıza göre tanımlayın.)

/interface wireless security-profiles
add authentication-types=wpa2-psk management-protection=allowed \
    mode=dynamic-keys name=kablosuz-guvenlik \
    wpa2-pre-shared-key=P4r0l4!!
/interface wireless
set [ find default-name=wlan1 ] disabled=no band=2ghz-g/n country=turkey \
    rate-set=configured basic-rates-b="" supported-rates-b="" \
    frequency=auto mode=ap-bridge wmm-support=enabled \
    security-profile=kablosuz-guvenlik ssid=Kablosuz24
set [ find default-name=wlan2 ] disabled=no band=5ghz-n/ac channel-width=20/40/80mhz-XXXX \
    country=turkey frequency=auto mode=ap-bridge wmm-support=enabled \
    security-profile=kablosuz-guvenlik ssid=Kablosuz5

Hem kablosuz hem de kablolu cihazlarımızı aynı yerel ağda birleştirmek için bir köprü oluşturuyoruz. WAN bağlantısı için kullanacağımız ether1 arayüzü dışındakileri oluşturduğumuz köprüye ekliyoruz. (Kullandığınız cihazdaki arayüzler, aşağıdakilerden farklı olabilir)

/interface bridge
add name=kopru
/interface bridge port
add bridge=kopru interface=ether2
add bridge=kopru interface=ether3
add bridge=kopru interface=ether4
add bridge=kopru interface=ether5
add bridge=kopru interface=wlan1
add bridge=kopru interface=wlan2

Oluşturduğumuz köprüde Mikrotik bizim ağ geçidimiz olacak ve kendi IP adresi 192.168.1.1 olacak. Bağlanan cihazlarımıza ise DHCP ile 192.168.1.100-192.168.1.200 aralığında IP adresi dağıtacak. Cloudflare DNS hizmetini kullanarak yerel ağ içerisindeki DNS sorgularına cevap verecek.

/ip address
add address=192.168.1.1/24 interface=kopru network=192.168.1.0
/ip dns
set allow-remote-requests=yes servers=1.1.1.1,1.0.0.1
/ip pool
add name=havuz ranges=192.168.1.100-192.168.1.200
/ip dhcp-server
add name=dhcp1 disabled=no interface=kopru address-pool=havuz
/ip dhcp-server network
add address=192.168.1.0/24 dns-server=192.168.1.1 gateway=192.168.1.1 netmask=24

Yerel ağ için arayüzleri yapılandırmayı bitirdik, şimdi sıra internet bağlantısında. Türkiye’de internet erişimi genellikle VLAN 35 üzerinden sağlanmaktadır. Bu nedenle ilk önce ether1 üzerinden otomatik IP alıyoruz ve sonrasında bir VLAN arayüzü tanımlıyoruz.

/interface vlan
add interface=ether1 name=vlan1 vlan-id=35
/ip dhcp-client
add disabled=no add-default-route=no interface=ether1

PPPoE bağlantısını VLAN arayüzü üzerinden gerçekleştireceğiz. (Servis sağlayıcınızdan alacağınız kullanıcı bilgilerinizi buraya gireceksiniz.)

/interface pppoe-client
add disabled=no interface=vlan1 add-default-route=yes \
    keepalive-timeout=disabled name=internet \
    user=kullaniciadi@millenicom password=parola

Pratik olması için WAN ve LAN arayüzlerini birer liste olarak tanımlayacağız.

/interface list
add name=WAN
add name=LAN
/interface list member
add interface=kopru list=LAN
add interface=internet list=WAN

LAN istemcilerinin trafiğini internete yönlendirmek için NAT ve güvenlik duvarı tanımlamalarını yapıyoruz.

/ip firewall filter
add action=accept chain=input comment=\
    "accept established,related,untracked" connection-state=\
    established,related,untracked
add action=drop chain=input comment="drop invalid" connection-state=\
    invalid
add action=accept chain=input comment="accept ICMP" protocol=icmp
add action=drop chain=input comment="drop all not coming from LAN" \
    in-interface-list=!LAN
add action=accept chain=forward comment="accept in ipsec policy" \
    ipsec-policy=in,ipsec
add action=accept chain=forward comment="accept out ipsec policy" \
    ipsec-policy=out,ipsec
add action=fasttrack-connection chain=forward comment="fasttrack" \
    connection-state=established,related
add action=accept chain=forward comment=\
    "accept established,related, untracked" connection-state=\
    established,related,untracked
add action=drop chain=forward comment="drop invalid" \
    connection-state=invalid
add action=drop chain=forward comment=\
    "drop all from WAN not DSTNATed" connection-nat-state=!dstnat \
    connection-state=new in-interface-list=WAN
/ip firewall nat
add action=masquerade chain=srcnat comment="masquerade" \
    ipsec-policy=out,none out-interface-list=WAN

Bu yapılandırmayı uyguladıktan sonra PPPoE bağlantısının sağlandığını ve Mikrotik’e bağlı cihazların internete erişebildiğini görebilirsiniz. İyi günlerde kullanın!